取势 明道 优术

作者为 扶 凯 发表

Conditional(条件) 的中间件和 URLMap 的应用有个共同点:它们都是 PSGI 应用,选择执行应用时要么通过 PSGI 取得相关的应用或者通过中间件来调度到指定的应用程序 .这是 PSGI 应用程序和中间件最美的地方.
今天的要谈一个其它例子.联合多个应用到一起. 联合是非常有用的,如果你有好几个应用程序,需要按一定的顺序运行,这会尝试着直到返回正常的响应,这有时也被称为链式设计,在一些 Web 应用中常常用到.象 mod_perl 的处理

联合应用
Plack::App::Cascade 可以让你合成多个应用以一定的顺序来运行,直到出现 non-404 responses 的返回.

use Plack::App::Cascade;
use Plack::App::File;
use Plack::App::URLMap;

my @paths = qw(
    /home/www/static
    /virtualhost/example.com/htdocs/static
    /users/miyagawa/public_html/images
);

my $app = Plack::App::Cascade->new;
for my $path (@paths) {
    my $file = Plack::App::File->new(root => $path);
    $app->add($file);
}

my $map = Plack::App::URLMap->new;
$map->mount("/static" => $app);
$map->to_app;

 

这个应用映射 /static 使用 URLMap.然后全部的请求会试着从 @paths 这三个目录中使用 App::File 应用来找文件,这可能对你想从多个目录多个目录联合起来取文件非常有用.

 

联合不同的应用

use CatalystApp;
CatalystApp->setup_engine('PSGI');
my $app1 = sub { CatalystApp->run(@_) };

use CGI::Application::PSGI;
use CGIApp;
my $app2 = sub {
    my $app = CGIApp->new({
        QUERY => CGI::PSGI->new($_[0]),
    });
    CGI::Application::PSGI->run($app);
};

use Plack::App::Cascade;
Plack::App::Cascade->new(apps => [ $app1, $app2 ])->to_app;

 

 这会建二个应用,一个 Catalyst 和一个 CGI::Application 的.然后按顺序运行这二个应用.假设在你的 URL 的结构中有一个 /what/ever.cat 是通过 Catalyst 的应用来服务和 /what/ever.cgiapp 是使用 CGI::Application 的 app.
这个是不是听起来非常疯狂,我想这是最好使用 URLMap 来映射两个不同的路径给应用,但如果你真的想联合,可能这是一个解决方法:)

这是我的译文,原文地址:http://advent.plackperl.org/2009/12/day-19-cascade-multiple-applications.html

 

来了就留个评论吧! 1个评论